a1c965da1e
Sixty-five headers sat side by side in include/, so `#include "irq.h"` said nothing about where irq.h was or what it belonged to, and errno.h, stat.h and fcntl.h at the top shadowed the system's for any host tool built with -I./include. They are in folders now -- arch/ core/ fs/ dev/ gfx/ net/ uapi/ (and ldls/ for the Linux driver layer) -- and every include names the folder, as Linux's do: "core/proc.h". Done mechanically and checked the hard way: the kernel built from this tree disassembles identically to the one built from the tree before it. The full image boots, and userland is the same set of programs. Paths in docs and comments follow; docs/guides/layout.md has a table of what is where, and tools/fix-includes.py rewrites old-style includes from the folders in the tree, for code written before this. Co-Authored-By: Claude Opus 5.5 <noreply@anthropic.com> Claude-Session: https://claude.ai/code/session_01S1giNvrHTrPMPw7V6x1kQ4
78 lines
1.8 KiB
ArmAsm
78 lines
1.8 KiB
ArmAsm
#include "arch/asm.h"
|
|
#include "arch/memlayout.h"
|
|
#include "arch/mmu.h"
|
|
|
|
# Each non-boot CPU ("AP") is started up in response to a STARTUP
|
|
# IPI from the boot CPU. Section B.4.2 of the Multi-Processor
|
|
# Specification says that the AP will start in real mode with CS:IP
|
|
# set to XY00:0000, where XY is an 8-bit value sent with the
|
|
# STARTUP. Thus this code must start at a 4096-byte boundary.
|
|
#
|
|
# Because this code sets DS to zero, it must sit
|
|
# at an address in the low 2^16 bytes.
|
|
#
|
|
# Startothers (in main.c) sends the STARTUPs one at a time.
|
|
# It copies this code (start) at 0x7000. It puts the address of
|
|
# a newly allocated per-core stack in start-4,the address of the
|
|
# place to jump to (mpenter) in start-8, and the physical address
|
|
# of entrypgdir in start-12.
|
|
#
|
|
# This code is identical to bootasm.S except:
|
|
# - it does not need to enable A20
|
|
# - it uses the address at start-4, start-8, and start-12
|
|
|
|
.code16
|
|
.global start
|
|
start:
|
|
cli
|
|
|
|
xorw %ax,%ax
|
|
movw %ax,%ds
|
|
movw %ax,%es
|
|
movw %ax,%ss
|
|
|
|
lgdt gdtdesc
|
|
movl %cr0, %eax
|
|
orl $CR0_PE, %eax
|
|
movl %eax, %cr0
|
|
|
|
ljmpl $(SEG_KCODE<<3), $(start32)
|
|
//PAGEBREAK!
|
|
|
|
.code32
|
|
start32:
|
|
movw $(SEG_KDATA<<3), %ax
|
|
movw %ax, %ds
|
|
movw %ax, %es
|
|
movw %ax, %ss
|
|
movw $0, %ax
|
|
movw %ax, %fs
|
|
movw %ax, %gs
|
|
|
|
# defer paging until we switch to 64bit mode
|
|
# set ebx=1 so shared boot code knows we're booting a secondary core
|
|
mov $1, %ebx
|
|
|
|
# Switch to the stack allocated by startothers()
|
|
movl (start-4), %esp
|
|
# Call mpenter()
|
|
call *(start-8)
|
|
|
|
movw $0x8a00, %ax
|
|
movw %ax, %dx
|
|
outw %ax, %dx
|
|
movw $0x8ae0, %ax
|
|
outw %ax, %dx
|
|
spin:
|
|
jmp spin
|
|
|
|
.p2align 2
|
|
gdt:
|
|
SEG_NULLASM
|
|
SEG_ASM(STA_X|STA_R, 0, 0xffffffff)
|
|
SEG_ASM(STA_W, 0, 0xffffffff)
|
|
|
|
|
|
gdtdesc:
|
|
.word (gdtdesc - gdt - 1)
|
|
.long gdt
|